Mac Magazin/MacEasy 57/Mac Magazin and MacEasy Magazine CD - Issue 57.iso/Updates⁄Treiber/Hermstedt/Marco ƒ/Modem Scripts/Hermstedt Marco/Hermstedt Marco

Text File | 1999-04-01 | 4KB | 217 lines

!*******************************************************************************
! Marco Skript für ARA
!*******************************************************************************
! Anwählvorgang
!*******************************************************************************
! Änderungen:
! 27.1.98 MP: ATW0 entfernt, sonst Überschreiben der Kontrollfeld Einstellung
! 7.5.98 MP: ATP4 für XLeo 2 Kanal
! 25.5.98 MP: dial timer verlängert
!
@ORIGINATE
!
serreset 57600, 0, 8, 1
HSReset 0 0 0 0 0 0
communicatingat 57600
!
!init. Marco
Jsr 22
ifTries 11 33
!
note "Nummer wird gewählt: ^1" 3
!
pause 10
!
flush
matchclr
matchstr 1 1 "CONNECT 57600"
matchstr 2 2 "CONNECT 38400"
matchstr 3 3 "CONNECT 19200"
matchstr 4 4 "CONNECT 9600"
matchstr 5 5 "CONNECT 4800"
matchstr 6 6 "CONNECT 2400"
matchstr 7 7 "CONNECT 1200"
matchstr 8 8 "CONNECT 300"
matchstr 9 20 "BUSY"
matchstr 10 30 "NO CARRIER"
matchstr 11 40 "NO ANSWER"
matchstr 12 50 "NO DIALTONE"
write "ATD^1\13"
matchread 600
Jump 33
!
!
@LABEL 1
serreset 57600, 0, 8, 1
jump 10
@LABEL 2
!serreset 38400, 0, 8, 1
setspeed 38400
communicatingat 38400
jump 10
@LABEL 3
serreset 19200, 0, 8, 1
jump 10
@LABEL 4
serreset 9600, 0, 8, 1
jump 10
@LABEL 5
serreset 4800, 0, 8, 1
jump 10
@LABEL 6
serreset 2400, 0, 8, 1
jump 10
@LABEL 7
serreset 1200, 0, 8, 1
jump 10
@LABEL 8
serreset 300, 0, 8, 1
jump 10
!
@LABEL 10
note "Verbindung zur Gegenstelle hergestellt." 3
HSReset 0 1 0 0 0 0
exit 0
!
@LABEL 20
note "Gegenstelle ist besetzt." 3
exit -6022
!
@LABEL 30
note "Die Verbindung zum ISDN Netz ist gestört." 3
exit -6021
!
@LABEL 40
note "Gegenstelle ist nicht erreichbar." 3
exit -6023
!
@LABEL 50
note "Das ISDN Netz ist überlastet." 3
exit -6020
!
!
!*******************************************************************************
! Antwortbetrieb
!*******************************************************************************
!
@ANSWER
!
serreset 57600, 0, 8, 1
HSReset 0 0 0 0 0 0
communicatingat 57600
!
!init. Marco
Jsr 22
ifTries 11 33
!
note "Warten auf Rückruf…" 3
pause 10
!
@LABEL 60
flush
@LABEL 61
matchclr
matchstr 1 65 "RING"
matchstr 2 1 "CONNECT 57600"
matchstr 3 2 "CONNECT 38400"
matchstr 4 3 "CONNECT 19200"
matchstr 5 4 "CONNECT 9600"
matchstr 6 5 "CONNECT 4800"
matchstr 7 6 "CONNECT 2400"
matchstr 8 7 "CONNECT 1200"
matchstr 9 8 "CONNECT 300"
matchstr 10  20 "BUSY"
matchstr 11  30 "NO CARRIER"
matchstr 12  40 "NO ANSWER"
matchstr 13  50 "NO DIALTONE"
matchread 600
jump 60
!
@LABEL 65
userhook 1
!note "Anruf wird entgegengenommen…" 3
jump 61
!
!*******************************************************************************
! Trennen
!*******************************************************************************
!
@HANGUP
!
@Label 70
HSReset 0 0 0 0 0 0
matchclr
matchstr 1 80 "OK"
matchstr 2 80 "NO CARRIER"
write "ATH\13"
matchread 20
! mind. 1sec warten
pause 11
!
matchclr
matchstr 1 71 "OK"
write "+++"
matchread 30
!
@Label 71
Pause 2
matchclr
matchstr 1 80 "OK"
matchstr 2 80 "NO CARRIER"
write "ATH\13"
matchread 20
Jump 33
!
@Label 80
!note "Verbindung zur Gegenstelle gelöst." 3
Pause 10
matchclr
matchstr 1 81 "OK"
! seriellen Port auf 57600bps, 8 Datenbits, 1 Stopbit, keine Parität
write "ATB16,0,0,8\13"
matchread 20
Jump 33
@Label 81
! etwas Zeit geben zum Umstellen der seriellen Konfiguration
Pause 2
serreset 57600, 0, 8, 1
communicatingat 57600
flush
Exit 0
!
! init. Marco
!
@Label 22
SetTries 0
matchclr
matchstr 1 23 "OK"
write "AT\13"
matchread 30
@Label 23
matchclr
matchstr 1 101 "OK"
write "ATP4\13"
matchread 30
@Label 101
Pause 2
@Label 102
Pause 2
matchclr
matchstr 1 103 "OK"
write "ATU*\13"
matchread 30
SetTries 11
Jump 104
@Label 103
Pause 2
matchclr
matchstr 1 104 "OK"
write "ATS0=1\13"
matchread 30
SetTries 11
@Label 104
Pause 10
Return
!
@Label 33
exit -6019